diff --git a/src/sys/lib/strcpy.S b/src/sys/lib/strcpy.S
new file mode 100644
index 0000000..655eb91
--- /dev/null
+++ b/src/sys/lib/strcpy.S
@@ -0,0 +1,44 @@
+.globl strcpy
+strcpy:
+        movl    4(%esp),%ecx            /* dst address */
+        movl    8(%esp),%edx            /* src address */
+        pushl   %ecx                    /* push dst address */
+
+        .align 2,0x90
+L1:     movb    (%edx),%al              /* unroll loop, but not too much */
+        movb    %al,(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    1(%edx),%al
+        movb    %al,1(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    2(%edx),%al
+        movb    %al,2(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    3(%edx),%al
+        movb    %al,3(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    4(%edx),%al
+        movb    %al,4(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    5(%edx),%al
+        movb    %al,5(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    6(%edx),%al
+        movb    %al,6(%ecx)
+        testb   %al,%al
+        je      L2
+        movb    7(%edx),%al
+        movb    %al,7(%ecx)
+        addl    $8,%edx
+        addl    $8,%ecx
+        testb   %al,%al
+        jne     L1
+L2:     popl    %eax                    /* pop dst address */
+        ret
+
diff --git a/src/sys/lib/strlen.S b/src/sys/lib/strlen.S
new file mode 100644
index 0000000..d301949
--- /dev/null
+++ b/src/sys/lib/strlen.S
@@ -0,0 +1,13 @@
+.globl strlen
+strlen:
+        pushl   %edi
+        movl    8(%esp),%edi            /* string address */
+        cld                             /* set search forward */
+        xorl    %eax,%eax               /* set search for null terminator */
+        movl    $-1,%ecx                /* set search for lots of characters */
+        repne                           /* search! */
+        scasb
+        notl    %ecx                    /* get length by taking complement */
+        leal    -1(%ecx),%eax           /* and subtracting one */
+        popl    %edi
+        ret